Lets have a look at some of the most common and fastest loops used in ActionScript 3. Is int really faster than uint and Number? Is while loop faster than for? Is pre-increment faster than post-increment? To test all of these I have created benchmark test application on wonderfl. App compares loops with 10.000.000 iterations and logs testing times. To compare different variable types, loop methods, increment / decrement modes, there are buttons grouping each test. Please be patient with your first click, the model Array is being generated (Link button also generates linked list). The first test compares Arrays, second one Vectors.

Loop Benchmark Test 1 uses Array:

Loop Benchmark Test 2 uses Vector.:

Loop Benchmar Test 4: Linked List vs. Final Linked List:

To sum it up fastest seems to be these methods:

Arrays
testForUintPreDecrement: 78 ms. *GLOBAL FASTEST*
testForUintPostDecrement: 78 ms. *GLOBAL FASTEST*
testForIntPostDecrement: 78 ms. *GLOBAL FASTEST*
testWhileUintPreDecrement: 78 ms. *GLOBAL FASTEST*
testWhileUintPostDecrement: 78 ms. *GLOBAL FASTEST*

Vectors
testForUintPreDecrement: 62 ms. *GLOBAL FASTEST*
testForIntPreDecrement: 62 ms. *GLOBAL FASTEST*
testForIntPostDecrement: 62 ms. *GLOBAL FASTEST*
testWhileIntPreIncrement: 62 ms. *GLOBAL FASTEST*
testWhileIntPostIncrement: 62 ms. *GLOBAL FASTEST*
testLinked: 62 ms. *GLOBAL FASTEST*

Those are my favorits:

public function testForIntPreDecrement():void
{
	for(var i:int = R - 1; i > -1; --i)
		modelArray[i];
}

public function testWhileUintPostDecrement():void
{
	var i:uint = modelArray.length;
	while(i--)
		modelArray[i];
}

public function testLinked():void
{
	var link:Linked = firstLink;
	while(link)
		link = link.next;
}

… that says it all:

• “for” and “while” loops can be equally fast, while “for each” loop is much slower
• “uint” and “int” is equally fast, and is much faster than “Number”
• “pre” vs. “post” is more less the same
• decrement mostly wins over increment, but in some cases is equally fast
• Linked-lists iteration performance equals to Vector and is better than Arryas
• when casting required, linked lists rules them all
• using ByteArray as list is not as fast as Array nor Vector

Code shortening can make your code more readable as well as more unreadable . While it is recommend to use coding conventions and standards, in some cases you can spare a lot of lines using some shortening. In fact there must not be a conflict between using convetion vs. using shortening, and soon after you get used to some “shortcuts”, your code may be reduced in reasonable amount of lines. Some reading about code optimization can be found here, this article extends optimizations.

with() statement

Establishes a default object to be used for the execution of a statement or statements, potentially reducing the amount of code that needs to be written. You can use multiple with() statemens:

with(new Date)
with(Math)
    trace(hours, sin(0));

List style dynamic switch

Sometimes when you need to “switch” simple input value into output value, all you need is to choose item from list.

var m:uint = 3;
trace(['','I','II','III','IV'][m]);
trace({a:'AA',b:'BB'}['b']);

New instantion / addChild combo

While DisplayObjectContainer.addChild(child) returns inserted child as DisplayObject, you can cast it.

var s:Sprite = Sprite(addChild(new Sprite()))

Anonymous functions

ActionScript lets you put function definition directly where you normally put reference.

addEventListener(Event.ENTER_FRAME, function(event:Event):void
{
    trace("anonymous enter frame")
});

In order to get a reference to the currently executing function use arguments.callee. If you need to removeEventListener, use reference not direct definition.

Omitting curly braces

It is possible to omit curly braces with some block statements (for, for each, if, while) on single statement

for(var i:uint=0;i<100;i++)
    trace(i)

Joining multiple statements into single-like

In order to create single statement from multiple statement (to omit curly braces) join statements with “,”.

var i:uint;
while(i<10)
    i++,trace(i);

Ternar / conditional operator

Pretty common, but worth mentioning

for(var i:uint = 0; i < 3; i++)
    trace(i == 1 ? "BOMB" : i);

Operators (pre-increment, post-increment…)

Also pretty common

var i:uint = 0;
trace(i++, ++i, i--, --i);
i += 1, i *= 2, i /= 2, i -= 1, i %= 2;

Modulo operator (%) and alternation

The Modulus operator(%) computes the remainder of division between 2 integers. Can be use for alternation (color etc.)

for(var i:uint = 0; i < 10; i++)
    trace(i%3 ? i : "BOMB");

Action assignment

Result of assignment is value itself.

var i:uint, j:uint = 0;
trace(i = j = 2);

for statement

for statement definition says:

for ([init]; [condition]; [next])

… it means you can use it very creative way

var i:uint = 0;
with(graphics)
for(clear(),lineStyle(1,0);i<10;x=y=100,i++)
    lineTo(x*i, y*i*i);

logical OR operator (||) and first valid

Result of statement using logical OR is the first valid element. It can substitute ternar operator in some cases

trace(null || 0 || "" || "BOMB" || "never");
trace(defined ? defined : "default") // equals to trace(defined || "default")

You can use || to shorten Boolean resulting ternar operator:

test ? true : false;
test || false;
test || 0;

Class Instantiating without “new”

Most common used is string delimiter (“), but there are also ones for XML, RegExp and Array

var x:XML = <data></data>;
var r:RegExp = /.*/i;

Shortest declaring for Array and Vector:

var a:Array = [1,2,3];
var v:Vector.<int> = new <int>[1,2,3]

Inline conditions

Use short circuit conditioning instead of if clause.

if(condition)
    doSomething();
// is the same as
condition && doSomething();

Boolean-izator (!!)

I guess the shortest way to get Boolean results.

!!test

Other

• E4X approach to XML processing, examples
• Code optimization

There has been a lot of articles written about how to optimize your flash / flex application frameRate. In most cases, you only need to have full frameRate when some animation is playing, or tweening etc., in other words when some visual changes are going on. FrameRateOptimizator class does exactly what you need. In default, it uses full frameRate when visual changes and when it stops, optimizator automatically switches to lower frameRate. Optimizator uses bitmapData to compare last state with actual state to catch any visual changes. By default snapshot is executed two times per second in low frameRate (inactive state), or one time per second in full frameRate state (active state), taking approximately not more than 10ms per execution (fast enough).

• sk.yoz.optimization.FrameRateOptimizator
• Application

FrameRateOptimizator.as

package sk.yoz.optimization
{
    import flash.display.BitmapData;
    import flash.display.DisplayObject;
    import flash.events.Event;
    import flash.events.EventDispatcher;
    import flash.events.MouseEvent;
    import flash.events.TimerEvent;
    import flash.geom.Matrix;
    import flash.utils.Timer;

    public class FrameRateOptimizator extends EventDispatcher
    {
        public var frameRateActive:uint = 24;
        public var frameRateInactive:uint = 2;

        protected var snapshot:BitmapData;

        protected var fpsp:uint;
        protected var _fps:uint;
        protected var fpsTimer:Timer;

        protected var root:DisplayObject;
        protected var _forceActive:Boolean = false;
        protected var _forceInactive:Boolean = false;
        protected var _mouseMoveActivation:Boolean = false;
        protected var _samplingScale:Number = 1;
        protected var samplingMatrix:Matrix = new Matrix();

        protected var samplingPeriod:uint = 1000;
        protected var activityTimer:Timer;

        public var debug:Boolean = false;

        public function FrameRateOptimizator(root:DisplayObject,
            frameRateActive:uint = 24, frameRateInactive:uint = 2,
            samplingPeriod:uint = 1000, mouseMoveActivation:Boolean = false,
            samplingScale:Number = 1):void
        {
            super();

            this.root = root;
            this.frameRateActive = frameRateActive;
            this.frameRateInactive = frameRateInactive;
            this.samplingPeriod = samplingPeriod;
            this.mouseMoveActivation = mouseMoveActivation;
            this.samplingScale = samplingScale;

            root.addEventListener(Event.ENTER_FRAME, rootEnterFrame);

            fpsTimer = new Timer(1000);
            fpsTimer.addEventListener(TimerEvent.TIMER, fpsTimerHandler);
            fpsTimer.start();

            var type:String = TimerEvent.TIMER_COMPLETE;
            activityTimer = new Timer(samplingPeriod, 1);
            activityTimer.addEventListener(type, activityTimerComplete);

            isActive = true;
        }

        [Bindable(event="fpsChanged")]
        public function get fps():uint
        {
            return _fps;
        }

        protected function set fps(value:uint):void
        {
            if(_fps == value)
                return;
            _fps = value;
            dispatchEvent(new Event("fpsChanged"));
        }

        public function set forceActive(value:Boolean):void
        {
            _forceActive = value;
            if(forceActive)
                isActive = true;
        }

        public function get forceActive():Boolean
        {
            return _forceActive;
        }

        public function set forceInactive(value:Boolean):void
        {
            _forceInactive = value;
            if(forceInactive)
                isActive = false;
        }

        public function get forceInactive():Boolean
        {
            return _forceInactive;
        }

        public function set mouseMoveActivation(value:Boolean):void
        {
            if(value == _mouseMoveActivation)
                return;
            _mouseMoveActivation = value;
            if(value)
                root.addEventListener(MouseEvent.MOUSE_MOVE, rootMouseMove);
            else
                root.removeEventListener(MouseEvent.MOUSE_MOVE, rootMouseMove);
        }

        public function get mouseMoveActivation():Boolean
        {
            return _mouseMoveActivation;
        }

        public function set isActive(value:Boolean):void
        {
            if(value && !forceActive && !forceInactive)
            {
                activityTimer.reset();
                activityTimer.start();
            }
            frameRate = suggestFrameRate(value);
        }

        public function set samplingScale(value:Number):void
        {
            _samplingScale = value;
            samplingMatrix = new Matrix();
            samplingMatrix.scale(value, value);
        }

        public function get samplingScale():Number
        {
            return _samplingScale;
        }

        protected function suggestFrameRate(active:Boolean):uint
        {
            if(forceActive)
                return frameRateActive;
            if(forceInactive)
                return frameRateInactive;
            return active ? frameRateActive : frameRateInactive;
        }

        protected function set frameRate(value:uint):void
        {
            if(value == frameRate)
                return;
            root.stage.frameRate = value;
            if(debug)
                trace("FrameRateOptimizator -> frameRate = " + value);
        }

        protected function get frameRate():uint
        {
            return root.stage.frameRate;
        }

        public function get isActive():Boolean
        {
            return frameRate == frameRateActive;
        }

        protected function rootEnterFrame(event:Event):void
        {
            fpsp++;
            if(!isActive && rootChanged)
                isActive = true;
        }

        protected function rootMouseMove(event:MouseEvent):void
        {
            isActive = true;
        }

        protected function get rootChanged():Boolean
        {
            var changed:Boolean = true;
            var bitmapData:BitmapData;
            try
            {
                var d0:Date = new Date();
                bitmapData = new BitmapData(
                    root.width * samplingScale, root.height * samplingScale);
                bitmapData.draw(root, samplingMatrix);
                if(snapshot)
                    changed = bitmapData.compare(snapshot) != 0;
                snapshot = bitmapData;
                trace(new Date().time - d0.time, "ms")
            }
            catch(error:Error)
            {
                snapshot = null;
                if(debug)
                    trace("FrameRateOptimizator Error: " + error.message);
            }
            return changed;
        }

        protected function fpsTimerHandler(event:TimerEvent):void
        {
            protected::fps = fpsp;
            fpsp = 0;
        }

        protected function activityTimerComplete(event:TimerEvent):void
        {
            isActive = rootChanged;
        }
    }
}

Application

<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml"
    applicationComplete="init()">
<mx:Script>
<![CDATA[
    import sk.yoz.optimization.FrameRateOptimizator;

    [Bindable]
    private var frameRateOptimizator:FrameRateOptimizator;

    private function init():void
    {
        frameRateOptimizator = new FrameRateOptimizator(this, 30);

        // trace new frameRate on change
        frameRateOptimizator.debug = true;

        // makes active frameRate on mouse move
        frameRateOptimizator.mouseMoveActivation = true;

        // always use active frameRate
        // frameRateOptimizator.forceActive = true;

        // always use inactive frameRate
        // frameRateOptimizator.forceInactive = true;

        // use active frameRate immediately
        //frameRateOptimizator.isActive = true;
    }
]]>
</mx:Script>
<mx:VSlider/>
</mx:Application>

Export code in debug mode and watch how frameRate changes (in trace console) when playing with slider. Try (un)comment mouseMoveActivation and see the difference.

Optimizer will not work if application contains any source object and (in the case of a Sprite or MovieClip object) all of its child objects do not come from the same domain as the caller, or are not in a content that is accessible to the caller by having called the Security.allowDomain() method. Read more about BitmapData.draw() SecurityError.

(10000000 / 32) uints in a Vector (10000000 bits) = ~7k
(10000000 / 32) uints in an Array (10000000 bits) = ~1228k

… and list of Booleans:

10000000 Booleans in a Vector = ~8k
10000000 Booleans in an Array = ~39070k

Read more about AVM2 Memory Considerations.

Apparat is an open source framework written in Java to optimize ABC, SWC and SWF files. The core of Apparat are its three file formats and their implementation:

• ABC (read and write ABC files, bytecode analysis and tools)
• SWC (read and write SWC files)
• SWF (read and write SWF files, tag implementations)

TAAS is a stackless representation of the ActionScriptBytecode. Read first results of TAAS, and see application before and after optimization.

The TAAS compiler is different from the ActionScript compiler since its input is not ActionScript source code but already compiled SWF or SWC files. Just like the haXe compiler can output AS3 instead of a SWF the TAAS compiler can do the same. Now if you add one and one together you see that the TAAS compiler can be used as a very strong decompiler. My own tests have shown that it will work flawlessly where other commercial decompilers output rubbish. Since the compiler behaves like the Flash Player it will “execute” the bytecode in order to parse it which means it has a very highlevel understanding of the structure inside the SWF. (Joa Ebert)

Look at the next code. There is too much nested tests. Soon you get lost with more and more nested levels:

function gimmeResult(a, b, c)
{
    var result;
    if(a)
    {
        if(b || c)
        {
            if(b && c < 0)
            {
                result = 1;
            }
            else
            {
                result = 2;
                // where am I?
            }
        }
        else
        {
            result = 3;
        }
    }
    else
    {
        result = 4;
    }
    return result;
}

Try to linearize code, it is much more cleaner for reading when no multiple nesting used:

function gimmeResult(a, b, c)
{
    if(!a)
        return 4;
    if(!b && !c)
        return 3;
    if(b && c < 0)
        return 1;
    return 2;
}

Sometimes your function does more things than it should. In this case, it chooses item and operate over it. But is it really good to use it this way?

function doSomething(key)
{
    for(i in list)
    {
        if(i == key)
        {
            if(item[i].value > 0)
            {
                item[i].value2 = 1;
            }
            else
            {
                item[i].value2 = 2;
            }
            if(item[i].value3 == 100)
            {
                while(item[i].value3 > 0)
                {
                    // where the hell I am now
                    item[i].value3--;
                }
            }
        }
    }
}

Split your code into separated functions. One selects your item, other operates over item. Result code is more cleaner and reusable.

function doSomething(key)
{
    item = getItem(key);
    if(!item)
        return;
    item.value2 = item.value > 0 ? 1 : 2;
    if(item.value3 != 100)
        return;
    while(item.value3 > 0)
        item.value3--;
}

function getItem(key)
{
    for(i in list)
        if(i == key)
            return list[i];
    return null;
}

Using continue in while cycle causes the current iteration to skip and go to the next one. Sometimes you do not need more processing from current iteration:

while(someIterator)
{
    // some processes here
    if(someIterator != "someValue")
    {
        // some processes here
        // and here
        // and here
    }
}

Using continue removes nesting, code is cleaner:

while(someIterator)
{
    // some processes here
    if(someIterator == "someValue")
        continue;
    // some processes here
    // and here
    // and here
}

When you do not need more iterations…

i = 100;
j = 0;
while(i)
{
    if(i > 90)
        j++;
    i--;
}
// 100 iterations means 100 "i > 50" tests

… you can use break to stop current while cycle and save unnecessary processing:

i = 100;
j = 0;
while(i)
{
    if(i <= 90)
        break;
    j++;
    i--;
}
// 10 iterations means 10 "i <= 50" tests

Where to go from here:

• Myth Buster – Benchmarking Loops
• Round up of ActionScript 3.0 and Flex optimization techniques and practices
• Optimizing Performance for theADOBE® FLASH® PLATFORM
• The Size of Empty
• Faster arithmetic – Flash Assembler (not ByteCode) : And you thought it couldn’t get faster
• GSkinner Talks