Facebook Query Language, or FQL, allows you to use a SQL-style interface to more easily query the same Facebook social data that you can access through other Facebook API methods (assuming your application has access!). Data returned for Facebook ActionScript Api are XML. You can access data via E4X after setting correct namespace. As for now (January 25, 2010), Facebook result defines xmlns=”http://api.facebook.com/1.0/” , but it may change in future, so lets make it dynamic…

Use e.g. extended FacebookLogger and add these lines

public function fql(query:String):void
{
	var call:FacebookCall = facebook.post(new FqlQuery(query));
	call.addEventListener(FacebookEvent.COMPLETE, fqlCallComplete);
}

private function fqlComplete(event:FacebookEvent):void
{
	var data:FacebookData = FacebookData(event.data);
	var xml:XML = XML(data.rawResult);
	var ns:Namespace = xml.namespace();
	default xml namespace = ns;

	var result:Array = [];
	for each(var user:XML in xml.user)
		result.push({uid:user.uid.toString(), name:user.name.toString()});

	default xml namespace = new Namespace("");
	dispatchEvent(new ResultEvent(ResultEvent.RESULT, false, true, result));
}

Notice xml.namespace() line. This method returns Namespace object used in main node (“http://api.facebook.com/1.0/”), so we can define it as default xml namespace. If you do not set empty default namespace after you finish parsing this XML, it may throw some errors later in parsing another XMLs.

this is our fql query:

FB.fql("SELECT uid, name FROM user WHERE uid = XXX")

and data.rawResult contains following XML object

<?xml version="1.0" encoding="UTF-8"?>
<fql_query_response xmlns="http://api.facebook.com/1.0/" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" list="true">
  <user>
    <uid>12345678</uid>
    <name>Some John Smith</name>
  </user>
  <user>
    <uid>12345679</uid>
    <name>Another John Smith</name>
  </user>...

Notice xmlns attribute in main node.

Soon, facebook api method PublishUserAction (flash api method) gets deprecated (December 20, 2009). It is suggested to use Facebook.streamPublish instead, and you can find this method in facebook flash api as PublishPost method. If you have problems to make it work take a look at the next simple example that is using image attachment and actionLinkData (as prelink anywhere).

Working part of application:

var message:String = "Hallo world";

var attachment:Object = {media: [{
   type: "image",
   src: "http://www.somedomain.com/someimage.jpg",
   href: "http://www.somedomain.com/sometarget.html"
}]};

var actionLinkData:ActionLinkData = new ActionLinkData();
actionLinkData.href = "http://www.someapplication.com/sometarget.html";
actionLinkData.text = "Uber application";

var post:PublishPost = new PublishPost(message, attachment, [actionLinkData], fbook.uid);
var call:FacebookCall = fbook.post(post);

Update (Feb 12, 2009): Type-proper usage:

import com.facebook.commands.stream.PublishPost;
import com.facebook.data.stream.ActionLinkData;
import com.facebook.data.stream.AttachmentData;
import com.facebook.data.stream.MediaTypes;
import com.facebook.data.stream.StreamMediaData;

var message:String = "Some status message"; // can be empty

var media:StreamMediaData = new StreamMediaData();
media.type = MediaTypes.PHOTO;
// MediaTypes defines "link", "video", "photo" but
// you should use "image", "flash", or "mp3"
// http://wiki.developers.facebook.com/index.php/Attachment_(Streams)

media.src = "http://www.somedomain.com/someimage.jpg";
media.href = "http://www.somedomain.com/go/somewhere.html";

var attachment:AttachmentData = new AttachmentData();
attachment.media = [media];
attachment.href = "http://www.somedomain.com/go/somewhere.html";
attachment.name = "Image title";
attachment.caption = "Some subtitle";
attachment.description = "Lorem Ipsum text about your image";

var link:ActionLinkData = new ActionLinkData();
link.href = "http://www.somedomain.com/your_application.html";
link.text = "Your application name"; 

var post:PublishPost = new PublishPost(message, attachment, [link], facebook.uid);

Read more about Stream.publish and Attachment (Streams)

By default, the photo and the Flash object are rendered in a space up to 90 pixels in both height or width, with an emphasis on scaling the image to be 90 pixels wide (90×90 px max).